ShaderLab 语法：剔除和深度测试 (Culling & Depth Testing)

剔除是一种避免渲染背对观察者的多边形的优化措施。所有多边形都有正面和背面。剔除基于大多数对象都是封闭的这一事实；如果有一个立方体，您将无法看到它背对您的那一面（但在它前面总有一个朝向您的面），所以您无需绘制背对您的那一面。因此被称作：背面剔除。

另一个使渲染看起来是正确的功能是深度测试。深度测试确保只有场景内最靠近表面的对象参与绘制。

语法

Cull Back | Front | Off

控制多边形的哪一面应该被剔除（即不绘制）

Back 不渲染背对观察者的多边形 (默认).

Front 不渲染面对观察者的多边形。用于从内向外翻转对象。

Off 不渲染面对观察者的多边形。用于特殊效果。

ZWrite On | Off

控制是否将对象的像素写入深度缓存（默认为 On）。如果要绘制实心对象，则使其处于开启 (on) 状态。如果想绘制半透明效果，则切换至 ZWrite 关 (ZWrite Off)。有关更多详细信息，请阅读以下内容。

ZTest Less | Greater | LEqual | GEqual | Equal | NotEqual | Always

如何执行深度测试。默认为 LEqual （绘制前面的对象或与现有对象有一段距离的对象；隐藏现有对象后面的对象）。

Offset Factor , Units

允许使用两个参数（因子 (factor)和单元 (units)）指定深度偏移，因子 (Factor)衡量多边形 Z 轴与 X 轴或 Y 轴的最大斜率，而单元 (units) 衡量可分解的最小深度缓存值。这使您可以强制地将一个多边形绘制在另一个多边形上，即使它们实际上处于相同位置。例如：Offset 0, -1 忽略多边形的斜率，使其靠近相机，而 Offset -1, -1 使多边形从切线角看时更加靠近相机。

示例

该对象将只渲染对象的背面：

Shader "Show Insides" {
    SubShader {
        Pass {
            Material {
                Diffuse (1,1,1,1)
            }
            Lighting On
            Cull Front
        }
    }
} 

尝试将其应用于立方体，并注意当您围绕几何结构进行旋转的时候，它看起来有多奇怪。这是因为您只是看到了这个立方体的内部。

具有深度写入的透明着色器

通常，半透明着色器不写入深度缓存。但是，这样可能会造成绘制顺序问题，特别是对于复杂的非凸网格。如果要像那样淡入或淡出网格，那么在渲染透明前使用填入深度缓存的着色器可能会有帮助。

Shader "Transparent/Diffuse ZWrite" {
Properties {
    _Color ("Main Color", Color) = (1,1,1,1)
    _MainTex ("Base (RGB) Trans (A)", 2D) = "white" {}
}
SubShader {
    Tags {"Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent"}
    LOD 200

    // 只渲染到深度缓存的额外通道
    Pass {
        ZWrite On
        ColorMask 0
    }

    // 从透明/漫反射粘贴到正向渲染通道
    UsePass "Transparent/Diffuse/FORWARD"
}
Fallback "Transparent/VertexLit"
}

调试法线 (Debugging Normals)

下一个更加有趣；首先我们使用法线顶点光照渲染对象，然后我们使用亮粉色渲染背面。这样会使在需要反转法线的地方都会有突出显示的效果。如果您看到物理控制的对象被任意网格“吸入”时，尝试将这个着色器分配给它们。如果任何粉红色的部分是可见的，那么在这些部分会把不慎接触到它的任何东西拉进去。

来试试吧：

Shader "Reveal Backfaces" {
    Properties {
        _MainTex ("Base (RGB)", 2D) = "white" { }
    }
    SubShader {
        // 渲染对象的正面部分。
        // 我们使用简单的白色材质并应用主纹理。
        Pass {
            Material {
                Diffuse (1,1,1,1)
            }
            Lighting On
            SetTexture [_MainTex] {
                Combine Primary * Texture
            }
        }

        // 现在让我们来渲染背面三角形
        // 用的是最让人兴奋的颜色：亮粉色！
        Pass {
            Color (1,0,1,1)
            Cull Front
        }
    }
} 

玻璃剔除 (Glass Culling)

控制剔除 (Controlling Culling) 多数情况来说比调试背面更有用。如果您有一个透明对象，在很多时候您会想要展示对象的背面。如果您不使用剔除 (Cull Off) 就进行渲染，很可能会出现某些背面与正面重叠的情况。

下面是一个可以用于凸对象（球体、立方体、汽车挡风玻璃）的简单着色器。

Shader "Simple Glass" {
    Properties {
        _Color ("Main Color", Color) = (1,1,1,0)
        _SpecColor ("Spec Color", Color) = (1,1,1,1)
        _Emission ("Emmisive Color", Color) = (0,0,0,0)
        _Shininess ("Shininess", Range (0.01, 1)) = 0.7
        _MainTex ("Base (RGB)", 2D) = "white" { }
    }

    SubShader {
        // 我们通过在子着色器中定义材质以便在多个通道中使用。
        // 此处定义材质对于所有包含的通道都采用默认值。
        Material {
            Diffuse [_Color]
            Ambient [_Color]
            Shininess [_Shininess]
            Specular [_SpecColor]
            Emission [_Emission]
        }
        Lighting On
        SeparateSpecular On

        // 设置 alpha 混合
        Blend SrcAlpha OneMinusSrcAlpha

        //渲染对象的背面部分。
        //如果对象为凸面体，这些背面部分总是比正面
        //更为深远。
        Pass {
            Cull Front
            SetTexture [_MainTex] {
                Combine Primary * Texture
            }
        }
        //渲染对象面对我们的那部分。
        //如果对象为凸面体，则正面部分要比
        //背面更靠近。
        Pass {
            Cull Back
            SetTexture [_MainTex] {
                Combine Primary * Texture
            }
        }
    }
} 

Page last updated: 2013-06-28